[Visual Basic 6.0]
'
' Sub LoadTrackingLayer
' Example VB script demonstrating how to add a tracking layer to the active map.
'
Sub LoadTrackingLayer()
    Dim strDataPath As String
    Dim piLayer As ILayer
    Dim piFeatureLayer As IFeatureLayer
    Dim piTrackingLayer As ITemporalLayer
    Dim piWSFact As IWorkspaceFactory
    Dim piWS As IWorkspace
    Dim piFeatureClass As IFeatureClass
    Dim piDatasets As IEnumDataset
    Dim piTrackingEnv As New TAExtension
    Dim piTrackingRenderer As ITemporalRenderer
    Dim piRenderer As New CoTrackSymbologyRenderer
    Dim piDoc As IMxDocument
    Dim piMap As IMap
                
    '
    ' Set up the document env
    '
    
    Set piDoc = Application.Document
        
    Set piMap = piDoc.FocusMap
    Set piTrackingRenderer = piRenderer
         
    '
    ' Set up path to tracking analyst tutorial data
    '
    
    strDataPath = "D:\arcgis\ArcTutor\Tracking_Analyst\Simple"
    
    '
    ' Get the hurricane feature class from the shape file
    '
    
    Set piWSFact = New ShapefileWorkspaceFactory
    Set piWS = piWSFact.OpenFromFile(strDataPath, 0)
    Set piDatasets = piWS.Datasets(esriDTAny)
    Set piFeatureClass = piDatasets.Next
    
    '
    ' Create a tracking layer
    '
    
    Set piTrackingLayer = New TemporalFeatureLayer
    Set piLayer = piTrackingLayer
    Set piFeatureLayer = piLayer
    
    '
    ' Set the temporal column and event id column
    ' Note: Set up the renderer before adding to layer
    '
    
    piTrackingRenderer.TemporalFieldName = "TA_DATE"
    piTrackingRenderer.TemporalObjectColumnName = "EVENTID"
    
    Set piTrackingLayer.Renderer = piRenderer
    
    '
    ' Set the data
    '
    
    Set piFeatureLayer.FeatureClass = piFeatureClass
    
    '
    ' Add layer to map
    '
            
    piMap.AddLayer piLayer
    
End Sub

[Visual Basic .NET, C#, C++]
No example is available for Visual Basic .NET, C#, or C++. To view a Visual Basic 6.0 example, click the Language Filter button in the upper-left corner of the page.