[Visual Basic 6.0]
Public Sub CreateLocator()
'+++ adds a new locator to the default local locator workspace
    Dim pLocatorManager As esriLocation.ILocatorManager2
    Dim pLocatorWorkspace As esriGeoDatabase.ILocatorWorkspace
    Dim pLocatorStyle As esriGeoDatabase.ILocatorStyle
    Dim pWorkspaceFactory As esriGeoDatabase.IWorkspaceFactory2
    Dim pFeatureWorkspace As esriGeoDatabase.IFeatureWorkspace
    Dim pDataset As esriGeoDatabase.IDataset
    Dim pReferenceDataTables As esriLocation.IReferenceDataTables
    Dim pEnumReferenceDataTable As esriLocation.IEnumReferenceDataTable
    Dim pReferenceDataTableEdit As esriLocation.IReferenceDataTableEdit
    Dim pLocator As esriGeoDatabase.ILocator
    
    '+++ open the default local locator workspace
    Set pLocatorManager = New esriLocation.LocatorManager
    Set pLocatorWorkspace = pLocatorManager.GetLocatorWorkspaceFromPath("")
    
    '+++ get a locator style on which to base the new locator
    Set pLocatorStyle = pLocatorWorkspace.GetLocatorStyle("US Streets with Zone (GDB)")
    
    '+++ open the feature workspace containing the reference data
    Set pWorkspaceFactory = New esriDataSourcesGDB.AccessWorkspaceFactory
    Set pFeatureWorkspace = pWorkspaceFactory.OpenFromFile("d:\workspace\StreetDatabase.mdb", 0)
    
    '+++ set the reference data on the new locator
    Set pDataset = pFeatureWorkspace.OpenFeatureClass("Street")
    Set pReferenceDataTables = pLocatorStyle
    Set pEnumReferenceDataTable = pReferenceDataTables.Tables
    pEnumReferenceDataTable.Reset
    Set pReferenceDataTableEdit = pEnumReferenceDataTable.Next
    Set pReferenceDataTableEdit.Name = pDataset.FullName
    
    '+++ store the locator if the reference data are properly specified
    If pReferenceDataTables.HasEnoughInfo Then
        Set pLocator = pLocatorWorkspace.AddLocator("My New Locator", pLocatorStyle, "")
    End If
    
End Sub

[Visual Basic .NET, C#, C++]
No example is available for Visual Basic .NET, C#, or C++. To view a Visual Basic 6.0 example, click the Language Filter button in the upper-left corner of the page.